別解、です。
　 A　 B　　C　　D　　 E　 F　G　　H　　 I
1　α　β　γ　 Θ　　　　 α β γ　　Θ
2　あ　　3 4/01 4/04 FALSE あ　1　4/03　4/06
3　い　　4 4/02 4/07　　　 あ　2　4/03　4/06
4　あ　　2 4/03 4/06　　　 う　2　4/04　4/07
5　え　　　4/03 4/11　　　 あ　3　4/04　4/06
6　あ　　3 4/04 4/06　　　 い　4　4/02　4/07
7　う　　2 4/04 4/07　　　　　　　　　　
8　あ　　1 4/03 4/06　　　　　　　　　　
9
10　　4/02 4/10

E2: =AND(C2>=B$10,D2<=C$10)

１行目に項目名を追加⇒セル E2 に式 =AND(C2>=B$10,D2<=C$10) を入力⇒
[データ]⇒[並べ替えとフィルター <詳細設定>]⇒[抽出先]として“指定した
範囲”目玉入れ⇒[リスト範囲]ボックス内にマウスカーソルを放り投げ入れて範囲
A1:D8 を撫で撫で($A$1:$D$8が入力される)⇒[検索条件範囲]ボックス内にマウス
カーソルを放り投げ入れて範囲 E1:E2 を撫で撫で($E$1:$E$2が入力される)⇒
[抽出範囲]ボックス内にマウスカーソルを放り投げ入れて範囲 F1:S1 を撫で撫で
($F$1:$I$1が入力される)⇒[OK]ボタンを「エイヤッ!」と叩き付け⇒列範囲 F:I を
選択⇒[データ]⇒[並べ替えとフィルター <並べ替え>]⇒[並べ替え]⇒“先頭行を…
使用する”にチェック入れ⇒[最優先されるキー]。[並べ替えのキー]、[順序]の
それぞれを、“β”、“セルの値”、“小さい順”を選択後、[OK]ボタンを
パシーッ
オ・シ・マ・イ

＞=IFERROR(@INDEX(A:A,1/LARGE(INDEX(($B$1:$B$7<>"")*($C$1:$C$7>=$B$9)*($D$1:$D$7<=$C$9)/ROW($B$1:$B$9),0),ROW(A1))),"")
  =IFERROR(INDEX(A$1:A$7,MOD(AGGREGATE(15,6,($B$1:$B$7*100000+ROW(B$1:B$7))/(($B$1:$B$7<>"")*($C$1:$C$7>=$B$9)*($D$1:$D$7<=$C$9)),ROW(B1)),100000)),"")

「@INDEX」と言う事は、もしかして、スピルが使えるサービスに入っていますか？　
その場合はA10セルに(他のセルにはコピーする必要ないです。全て空白にしておかないと逆にエラーになります）
　　↓
=SORT(FILTER(A1:D7,(B1:B7<>"")*(C1:C7>=B9)*(D1:D7<=C9)),2)

	A	B	C	D
1	あ	3	4月1日	4月4日
2	い	4	4月2日	4月7日
3	あ	2	4月3日	4月6日
4	え		4月3日	4月11日
5	あ	3	4月4日	4月6日
6	う	2	4月4日	4月7日
7	あ	1	4月3日	4月6日
8				
9		4月2日	4月10日	
10	い	4	4月2日	4月7日
11	あ	2	4月3日	4月6日
12	あ	3	4月4日	4月6日
13	う	2	4月4日	4月7日
14	あ	1	4月3日	4月6日

以上のようにA1:D7のようなデータがあり
B列空白以外、C列B9以上、D列C9以下で抽出したのが
A10:D14です。A10には以下の数式を書きました。
=IFERROR(@INDEX(A:A,1/LARGE(INDEX(($B$1:$B$7<>"")*($C$1:$C$7>=$B$9)*($D$1:$D$7<=$C$9)/ROW($B$1:$B$9),0),ROW(A1))),"")

最終的には以下のようにB列で昇降順に並べ替えが必要です。
			
	あ	1	4月3日	4月6日
	あ	2	4月3日	4月6日
	う	2	4月4日	4月7日
	あ	3	4月4日	4月6日
	い	4	4月2日	4月7日

A10の数式をどう変更すればよろしいかお教えください。
ちなみにエクセル2016使用です。