戻る  □VBAのサロン  □ 使用方法  □ 新着記事  □ 新規に質問する!  □ トピック一覧  □ 検索  □ 過去ログ
[ 最新記事及び返信フォームをトピックトップへ ]
このトピック参照回数 :
別ブックシートのデータを参照を一個一個やっていて良い方法がないでしょうか?

    [131310] 別ブックシートのデータを参照を一個一個やっていて良い方法がないでしょうか?-

    ■親トピック/記事引用/メール受信=OFF■

    □投稿者/ フジ -(2020/05/07(11:33))
    □U R L/

      エクセル別シートの一個のセルを入力セルにコピペが大変で困ってる』(フジムラ)

      エクセル初心者で説明が下手かもしれないですが
      今誰がどの車を何キロ走行したか
      を車別にまとめてあるエクセルブックがあり
      小型車 4月 5月 6月…
      Aさん  50km 25km 10km…
      Bさん  45km 5km 0km
      Cさん  …
      と車別毎にシート分けされてるブックとこの車別を参照して

                    Aさん
        小型車 大型車 タクシー  
      4月 50km 35km 5km…
      5月 25km 3km 0km…
      6月…
      と乗った人の走行距離の詳細が車別の各項目をリンクして
      作られているのですが
      (このブックの数式は全部=車別A3みたいな感じです)
      引き継ぎでこの仕事をした時にこのリンクがズレや消滅
      箇所が多い上に人数も1人10台 各月1年を
      50人分くらいを
      現在=入力して小型のAさんの4月の距離のセル押して
      エンター次は同じ感じで小型の5月の距離を押してエンター
      と一個一個やってたんですけど
      心が折れかけたため相談してみようと決意しました。
      このデータを作った方は退職していて
      エクセルが強い人がいないので困っています
      どうか良い方法はないでしょうか?
      お願いします。


      ++++++++++++++++++++
      OS      ⇒Windows XP
      Version⇒Excel 2007
      ++++++++++++++++++++




    [131311] Re[1]: 別ブックシートのデータを参照を一個一個やっていて良い方法がないでしょうか?-

    記事引用/メール受信=OFF■

    □投稿者/ bi -(2020/05/07(13:15))
    □U R L/

      すみませんが回答ではありません。
      ここのサイトはマルチポスト禁止です。どちらかで続けてください。




    [131313] Re[2]: 別ブックシートのデータを参照を一個一個やっていて良い方法がないでしょうか?-

    記事引用/メール受信=OFF■

    □投稿者/ フジムラ -(2020/05/07(15:00))
    □U R L/

      すいません
      注意書きを見ていませんでした。
      もう一つの方は削除依頼しました。
      本当に申し訳ありません。




    [131316] Re[3]: 別ブックシートのデータを参照を一個一個やっていて良い方法がないでしょうか?-

    記事引用/メール受信=OFF■

    □投稿者/ 半平太 -(2020/05/07(20:43))
    □U R L/
      こういうのはマクロじゃないと辛いです。
      
      「小型車」シートの「シート見出」を右クリックして、
      VBE画面を出したら、画面中央の白いエリアに
      後記マクロコードを貼り付け、F5キー押下で実行する。
      
      すると新規ブックが作成され、集計が完了する。
      
      <小型車シート サンプル>
       行  ___A___  __B__  __C__  __D__  _ E _  _ F _  __G__
        1  小型車   4月    5月    6月    7月    8月    9月  
        2  Aさん    50km   25km   10km   11km   12km   13km 
        3  Bさん    45km   5km    0km    1km    2km    3km  
      
      <大型車シート サンプル>
       行  ___A___  __B__  __C__  __D__  _ E _  _ F _  __G__
        1  大型車   4月    5月    6月    7月    8月    9月  
        2  Aさん    150km  25km   10km   11km   12km   13km 
        3  Bさん    45km   5km    0km    1km    2km    103km
      
      <タクシーシート サンプル>
       行  ____A____  ___B___  __C__  __D__  _ E _  _ F _  ___G___
        1  タクシー   4月      5月    6月    7月    8月    9月    
        2  Aさん      1050km   25km   10km   11km   12km   13km   
        3  Bさん      45km     5km    0km    1km    2km    1003km 
      
                  
       行 _A_ ___B___ ___C___ ____D____      行 _A_ ___B___ ___C___ ____D____
        1     小型車  大型車  タクシー        1     小型車  大型車  タクシー 
        2 4月 50km    150km   1050km          2 4月 45km    45km    45km     
        3 5月 25km    25km    25km            3 5月 5km     5km     5km      
        4 6月 10km    10km    10km            4 6月 0km     0km     0km      
        5 7月 11km    11km    11km            5 7月 1km     1km     1km      
        6 8月 12km    12km    12km            6 8月 2km     2km     2km      
        7 9月 13km    13km    13km            7 9月 3km     103km   1003km   
      
      ’貼り付けるマクロ
      Sub Sample()
          Dim dicDstn As Object, dicName As Object
          Dim dicMonth As Object, dicKind As Object
          Dim rToProc As Range
          Dim RW As Long, CL As Long
          Dim ws As Worksheet
          Dim key
          Dim i As Long
          Dim Temp, itm
          
          Set dicDstn = CreateObject("Scripting.Dictionary")
          Set dicName = CreateObject("Scripting.Dictionary")
          Set dicMonth = CreateObject("Scripting.Dictionary")
          Set dicKind = CreateObject("Scripting.Dictionary")
          
          Rem データ収集
          With Me.Parent
              For Each ws In Worksheets
                  dicKind(ws.Name) = Empty
                  
                  Set rToProc = ws.Range("A1").CurrentRegion
                  
                  For Each key In rToProc.Offset(, 1).Rows(1).Value
                      If Not IsEmpty(key) Then
                          dicMonth(key) = Empty
                      End If
                  Next
                  
                  For Each key In rToProc.Offset(1).Columns(1).Value
                      If Not IsEmpty(key) Then
                          dicName(key) = Empty
                      End If
                  Next
                  
                  For RW = 2 To rToProc.Rows.Count
                      
                      For CL = 2 To rToProc.Columns.Count
                          With rToProc
                              key = ws.Name & "#!#" & .Rows(1).Cells(RW, 1) & "#!#" & .Columns(1).Cells(1, CL)
                              dicDstn(key) = .Cells(RW, CL).Value
                          End With
                      Next CL
                  Next RW
              Next
          End With
          
          '人別ブックを作成して、データ埋め込み
          Temp = Application.SheetsInNewWorkbook
          Application.SheetsInNewWorkbook = dicName.Count
          Workbooks.Add
          Application.SheetsInNewWorkbook = Temp
          Application.ScreenUpdating = False
          
          i = 0
          For Each itm In dicName
              i = i + 1
              With ActiveWorkbook.Worksheets(i)
                  .Name = itm
                  .Range("B1").Resize(1, dicKind.Count) = dicKind.keys
                  .Range("A2").Resize(dicMonth.Count, 1) = Application.Transpose(dicMonth.keys)
                  
                  For CL = 2 To dicKind.Count + 1
                      For RW = 2 To dicMonth.Count + 1
                          key = .Cells(1, CL) & "#!#" & itm & "#!#" & .Cells(RW, 1)
                          .Cells(RW, CL).Value = dicDstn(key)
                      Next RW
                  Next CL
              End With
          Next
          Application.ScreenUpdating = True
      End Sub


      この記事にはVBAのコードが含まれています。

      緑の太文字→注釈
      茶色の太文字→条件分岐
      赤の太文字→ループ
      青の太文字→その他




    [131319] Re[4]: 別ブックシートのデータを参照を一個一個やっていて良い方法がないでしょうか?-

    記事引用/メール受信=OFF■

    □投稿者/ フジムラ -(2020/05/07(23:42))
    □U R L/

      ありがとうございます!!
      明日早速試してみます!!
      光明が見えました本当にありがとうございます。




    [131320] Re[5]: 別ブックシートのデータを参照を一個一個やっていて良い方法がないでしょうか?-

    記事引用/メール受信=OFF■

    □投稿者/ 半平太 -(2020/05/08(07:42))
    □U R L/
      >「小型車」シートの「シート見出」を右クリックして、
      
       (正)
       「小型車」シートの「シート見出」を右クリックして、サブメニューの「コードの選択」を選び



このトピック内容の全ページ数 / [0]

このトピックに書きこむ
Name/
E-Mail/

└>このツリーのレス記事をメールで受信しますか? YES/ NO/
Title/
URL/
Comment/ 通常モード->  図表モード-> (←の場合適当に改行を入れて下さい)
タグが使用できます。例 ⇒ <font color="blue">文字</font>
解決!!ありがとうございました! 解決       保留中です・・・ 保留        迷宮入りorほかあたって見ます・・ 迷宮入       すいませ〜ん。誰か〜! Help! ←※回答者専用
解決したらチェック       保留(コードテスト中など・・)         解決不可orレスが全く付かなくてほかのサイトに行くときなど・・
削除キー/
(半角8文字以内) 


- Child Forum -
Edit:ゆう-G