長年、回答案を見ていますが、条件付き書式を網羅的に解明できた人はいません。
(勘違いしている人はパラパラいます）

そもそも、網羅的な解明が必要になることも稀なんで、トライする人が絶対的に少ない。
難度の高さと必要性の兼ね合いを考えると、コスパが悪すぎる作業ですからねぇ・・

そんな事情なので、難度を下げる為、
先ずどんな条件付き書式が設定されているのか全部書き出して見るのがいいと思います。
その現実的な範囲内で対策を考えればいいのであれば、少しは楽になります。

条件付き書式は、RangeオブジェクトのFormatConditionsプロパティに3つのITEMとして入っているので
それぞれ、Type、Operator、Formula1、Formula2を書き出せば、何かピンとくるものがあると思います。

条件が真であるかどうかは、EVALUATE関数で調べられると思います。

先ほど、
「Excel VBA 条件付き書式の取得」
で調べてみて下さい。
と回答した物です。

上記で検索した結果見つかったサイトを見ながら、
以下のようなサンプルコードを作成しました。

私も、やったことなかったので、
上記で調べて「これならできる」と思ったのですが、
実際に動作確認をせずに回答してしまいました。
申し訳ありません。

なので、試しに作ってみました。

以下のサンプルコードは、
「指定の値を含むセルだけを書式設定」
「次の値に等しい」
の条件付き書式の物ですが、
条件付き書式の種類によってどうするかを
コード追加していけば可能かと思います。


'A列の条件付き書式の何番目の条件に当たるかを表示する。
'サンプルの為、一致する条件がない場合は考慮していない。
'Excel2003の動作環境がないので、動作確認はWin10、Microsoft365
Sub Sample()
    Dim fcs As FormatConditions
    Dim fc As FormatCondition
    Dim lngRow As Long
    Dim cnt As Long
    
    For lngRow = 1 To Cells(Rows.Count, 1).End(xlUp).Row
        Set fcs = Range("A" & lngRow).FormatConditions
        For Each fc In fcs
            cnt = cnt + 1
            If CStr(Mid(fc.Formula1, 2)) = CStr(Range("A" & lngRow).Value) Then
                Debug.Print cnt & "番目の条件と一致しています"
                Exit For
            End If
        Next
        cnt = 0
    Next lngRow
    
End Sub

半平太様の仰る勘違いだとしたらすみません。

 昔のエクセルファンクラブの回答をメモしておいたものです
        '対象セルの表示カラー値（RGB値）を取得する。
        'ここで言う表示カラーとは塗りつぶし色、または、条件付書式によって表示
されている色のこと。
        'セルに条件付書式が設定されていなかった場合は、セルの塗りつぶし色を返
す。
        '
        '引数
        '　aCell ： 対象セル（必ず単一のセルを指定すること）
        '
        '戻り値
        '　表示カラー値（RGB値）
        '
        ' By Meighth
h ttp://www.keep-on.com/excelyou/2000lng4/200005/00050350.txt
        '
        Function GetColorRGB(ByVal aCell As Range) As Long
            Dim COL As Long, FC As FormatCondition, ConditionOK As Boolean
            Dim OldRefStyle As Long
            Dim f1, f2

            COL = aCell.Interior.Color

            'セル参照形式を R1C1 にする。
            OldRefStyle = Application.ReferenceStyle
            Application.ReferenceStyle = xlR1C1

            With aCell.Worksheet
                For Each FC In aCell.FormatConditions
                    ConditionOK = False

                    '条件付書式の Formula1 と Formula2 を取得
                    f1 = """": f2 = """"""
                    On Error Resume Next
                    f1 = Application.ConvertFormula(FC.Formula1, xlR1C1,
xlR1C1, xlAbsolute, aCell)
                    f2 = Application.ConvertFormula(FC.Formula2, xlR1C1,
xlR1C1, xlAbsolute, aCell)
                    On Error GoTo 0

                    If FC.Type = xlCellValue Then
                        Select Case FC.Operator
                            Case xlEqual
                                If aCell.Value = .Evaluate(f1) Then
ConditionOK = True
                            Case xlNotEqual
                                If aCell.Value <> .Evaluate(f1) Then
ConditionOK = True
                            Case xlGreater
                                If aCell.Value > .Evaluate(f1) Then
ConditionOK = True
                            Case xlGreaterEqual
                                If aCell.Value >= .Evaluate(f1) Then
ConditionOK = True
                            Case xlLess
                                If aCell.Value < .Evaluate(f1) Then
ConditionOK = True
                            Case xlLessEqual
                                If aCell.Value <= .Evaluate(f1) Then
ConditionOK = True
                            Case xlBetween
                                If .Evaluate(f1) <= aCell.Value And
aCell.Value <= .Evaluate(f2) Then ConditionOK = True
                            Case xlNotBetween
                                If aCell.Value < .Evaluate(f1)
Or .Evaluate(f2) < aCell.Value Then ConditionOK = True
                        End Select
                    ElseIf FC.Type = xlExpression Then
                        On Error Resume Next
                        If .Evaluate(f1) Then
                            If Err.Number = 0 Then
                                ConditionOK = True
                            End If
                        End If
                        On Error GoTo 0
                    End If

                    If ConditionOK Then
                        COL = FC.Interior.Color
                        Exit For
                    End If
                Next FC
            End With

            'セル参照形式を元に戻す。
            Application.ReferenceStyle = OldRefStyle
            GetColorRGB = COL
        End Function

MKさん、ひみつのめもさん、ありがとうございます。
MKさん、debug.printはあまり使いませんがちゃんと分かっています。
匿名さんのコード、
    If CStr(Mid(fc.Formula1, 2)) = CStr(Range("A" & lngRow).Value) Then
　ここに手を入れたらチャンと機能しました。
匿名さん、ありがとうございました。

ひみつのめもさん、凄いです。
チャンと条件付き書式で着けた色が把握できました。
ただ、「数式が」だけで、「値が」の方はエラーになります。
細かく読めていないからで、しっかり読んでみます。
チャンと読めれば、最低限必要なコードも掛けるかなと思います。
もう少し勉強します。

ひみつのめもさんの参考コードを流用させて頂くと、
こんな感じでしょうか。
　↓
Sub showPriority()
    Dim target As Range
    Dim msg As String
    
    Set target = Range("B3") 'サンプルとしてB3セルをチェックに行った場合

    If target.FormatConditions.Count = 0 Then
        MsgBox "条件付き書式の設定がありません"
        Exit Sub
    End If
    
    ret = getPriority(target)
    
    If ret = 0 Then
        msg = "該当なし"
    Else
        msg = ret & "番目が該当"
    End If

    MsgBox msg
End Sub

Private Function getPriority(ByVal aCell As Range) As Long
    Dim fc As FormatCondition, ConditionOK As Boolean
    Dim OldRefStyle As Long
    Dim f1, f2
    
    'セル参照形式を R1C1 にする。
    OldRefStyle = Application.ReferenceStyle
    Application.ReferenceStyle = xlR1C1
    
    With aCell.Worksheet
        cnt = 0 '優先順位を初期化
        ConditionOK = False
    
        For Each fc In aCell.FormatConditions
            cnt = cnt + 1
            
            '条件付書式の Formula1 と Formula2 を取得
            f1 = """": f2 = """"""
            On Error Resume Next
            f1 = Application.ConvertFormula(fc.Formula1, xlR1C1, xlR1C1, xlAbsolute, aCell)
            f2 = Application.ConvertFormula(fc.Formula2, xlR1C1, xlR1C1, xlAbsolute, aCell)
            On Error GoTo 0
            
            If fc.Type = xlCellValue Then
                Select Case fc.Operator
                    Case xlEqual
                        If aCell.Value = .Evaluate(f1) Then ConditionOK = True
                    Case xlNotEqual
                        If aCell.Value <> .Evaluate(f1) Then ConditionOK = True
                    Case xlGreater
                        If aCell.Value > .Evaluate(f1) Then ConditionOK = True
                    Case xlGreaterEqual
                        If aCell.Value >= .Evaluate(f1) Then ConditionOK = True
                    Case xlLess
                        If aCell.Value < .Evaluate(f1) Then ConditionOK = True
                    Case xlLessEqual
                        If aCell.Value <= .Evaluate(f1) Then ConditionOK = True
                    Case xlBetween
                        If .Evaluate(f1) <= aCell.Value And aCell.Value <= .Evaluate(f2) Then ConditionOK = True
                    Case xlNotBetween
                        If aCell.Value < .Evaluate(f1) Or .Evaluate(f2) < aCell.Value Then ConditionOK = True
                End Select
                
            ElseIf fc.Type = xlExpression Then
                
                On Error Resume Next
                If .Evaluate(f1) Then
                    If Err.Number = 0 Then
                        ConditionOK = True
                    End If
                End If
                On Error GoTo 0
            End If
            
            If ConditionOK Then
                Exit For
            End If
        Next fc
        
    End With
    
    'セル参照形式を元に戻す。
    Application.ReferenceStyle = OldRefStyle
    getPriority = IIf(ConditionOK, cnt, 0)
End Function


この記事にはVBAのコードが含まれています。

緑の太文字→注釈
茶色の太文字→条件分岐
赤の太文字→ループ
青の太文字→その他

＞多分excel2003に機能がないためと思います。
フーム、私はもっと古いXL2000でテストして問題なかったので、
その後、XL2003になった時にも仕様の変更があったんでしょうね。

これでやってみてください。
＞ f1 = Application.ConvertFormula(fc.Formula1, xlR1C1, xlR1C1, xlAbsolute, aCell)
＞ f2 = Application.ConvertFormula(fc.Formula2, xlR1C1, xlR1C1, xlAbsolute, aCell)
  　　　　　                                      ↓変更
   f1 = Application.ConvertFormula(fc.Formula1, xlA1, xlR1C1, xlAbsolute, aCell)
   f2 = Application.ConvertFormula(fc.Formula2, xlA1, xlR1C1, xlAbsolute, aCell)

なお、XL2007以降は条件付き書式の仕様が大幅に変わったので、全く別の話になります。

＞「値が」ではこれまでと変わらず、「サポートしていない」のエラー、
＞「数式が」では全てが「該当なし」になってしまいました。
あれ？　改悪になっちゃいましたか・・とほほ
すると「XL2003になった時にも仕様の変更があった」とは言えないです。
変更は元に戻してください。

さて、条件の判定はEvaluate関数でやっているんですが、
その関数は強力ではありますが、全ての数式文字列を評価できる訳ではありません。

浦島太郎さんのレスから、大して変わったことはやっていないであろうと思ったのですが、
そうでもないのかも知れません。

トラブっているセルの一つを例に、どんな条件付き書式を設定しているのか開示いただけませんか？
以前提示いただいた、
このセルじゃないですよね？
　↓　
＞B3の条件付き書式です。
＞条件1 値が69以下　水色
＞条件2 値が70から109　色なし
＞条件3 値が110以上　赤色

フーム、修正前に戻してテストしましたが、こちらでは正常終了します。

＞条件1　値が　次の値に等しい セルの値1 書式＝緑
＞条件2　値が　次の値に等しい セルの値2 書式＝紫
＞条件3　値が　次の値に等しい セルの値3 書式＝赤
＞です。
＞そして、このケースで「オブジェクトはこの、、、サポートしていません」のエラーになります。

この条件付き書式が設定されているセルのアドレスはどこですか？　　　　値は何になっていますか？
セルの値1 はどこのセルですか？　そこは数式ですか、手入力値ですか？　値は何になっていますか？
セルの値2 はどこのセルですか？　そこは数式ですか、手入力値ですか？　値は何になっていますか？
セルの値3 はどこのセルですか？　そこは数式ですか、手入力値ですか？　値は何になっていますか？

事象再現しました！

? evaluate("1")
これが「オブジェクトはこのプロパティまたはメソッドをサポートしていません」エラーになる。

古いバージョンの信じられないようなお粗末バグです。
以下に変更してください。

＞f1 = Application.ConvertFormula(fc.Formula1, xlR1C1, xlR1C1, xlAbsolute, aCell)
＞f2 = Application.ConvertFormula(fc.Formula2, xlR1C1, xlR1C1, xlAbsolute, aCell)
　　　　　　↓
  f1 = Application.ConvertFormula(fc.Formula1, xlR1C1, xlR1C1, xlAbsolute, aCell)
  f2 = Application.ConvertFormula(fc.Formula2, xlR1C1, xlR1C1, xlAbsolute, aCell)
  f1 = IIf(Left(f1, 1) = "=", f1, "(" & f1 & ")") '古いバージョンのバグ対策
  f2 = IIf(Left(f2, 1) = "=", f2, "(" & f2 & ")") '古いバージョンのバグ対策