こんばんは。

データベース検索システムを作成したのですが、

「DB」シートには列数　28　行数　100行の構成になっており
数式が入っている列があるので「型が一致しません」というエラーになります。

ご教授よろしくお願いいたします。


Sub DBSearch()
    
    Call kousin
    Call midashioff
    
    Dim rowNo As Long, colNo As Long
    Dim sStr As String
    Dim dataDB As Variant
    Dim i As Long, j As Long

    
    'DBの取得
    With Worksheets("DB")
        
        rowNo = .Cells(.Rows.Count, "B").End(xlUp).Row                  '行の最終行取得
        colNo = .Cells(1, .Columns.Count).End(xlToLeft).Column          '列の最終列取得
        dataDB = .Range(.Cells(1, "A"), .Cells(rowNo, colNo)).Value     'DBの範囲取得
        
    End With
    
    With Worksheets("検索")
        
        sStr = .Range("A2").Value       '検索値のセルを取得
        
        '検索結果の削除
        rowNo = .Cells(.Rows.Count, "A").End(xlUp).Row
        If rowNo >= 4 Then
            .Range(.Rows(4), .Rows(rowNo)).Delete
        End If
        
        '項目名
        With .Range(.Cells(4, "A"), .Cells(4, UBound(dataDB, 2)))
            .Value = dataDB
            .Interior.Color = RGB(0, 176, 80)
        End With
        
        '検索結果
        rowNo = 4
        For i = 2 To UBound(dataDB, 1)
            Dim memo As String: memo = ""
            For j = 1 To UBound(dataDB, 2)
                memo = memo & dataDB(i, j)　　　　　’←ここで止まります
            Next j
            If memo Like "*" & sStr & "*" Then
                rowNo = rowNo + 1
                For j = 1 To UBound(dataDB, 2)
                    .Cells(rowNo, j) = dataDB(i, j)
                Next j
            End If
        Next i
        
        '枠組み
        .Range(.Cells(4, "A"), .Cells(rowNo, UBound(dataDB, 2))) _
            .Borders.LineStyle = xlContinuous
        
    End With
               
    '見出し固定
    Call midashion

End Sub


Sub kousin()

    Worksheets(1).Range("A5").CurrentRegion.Offset(2, 0).Copy
    Worksheets("DB").Range("A2").PasteSpecial Paste:=xlPasteValues
    Application.CutCopyMode = False
    Worksheets("検索").Range("A2").Select

End Sub


Sub midashioff()

    Rows(5).Select
    ActiveWindow.FreezePanes = False
    
End Sub


Sub midashion()

    Rows(5).Select
    ActiveWindow.FreezePanes = True
    
End Sub

＞ memo = memo & dataDB(i, j)　　　　　’←ここで止まります
で、その時 dataDB(i, j)の値はどうなっているんですか？

エラーなんですか？
エラーだったとして、止まらせないでどう進展させたいのですか？

＞数式が入っている列があるので「型が一致しません」というエラーになります。

「dataDB = .Range(.Cells(1, "A"), .Cells(rowNo, colNo)).Value」
となっているので、dataDBには、数式が入っていないはずですが…
Valueプロパティについて調べてみて下さい。

例えば、A1セルに「=SUM(A2:A5)」と入れて
Range("B1").Value = Range("A1").Value
をVBAで実行すると、B1セルには数式は入りません。

「型が一致しません」という事は、

「dataDB」というバリアント型の変数の型が、
「dataDB(i, j)」という型になっていないのではないでしょうか。

VBEのローカルウインドウを見てみて下さい。

こんな事かな？

＞ memo = memo & dataDB(i, j)　　　　　’←ここで止まります
　　↓
    If IsError(dataDB(i, j)) Then
        Select Case dataDB(i, j)
            Case CVErr(xlErrDiv0)
                memo = memo & "#DIV/0!"
            Case CVErr(xlErrNA)
                 memo = memo & "#N/A"
            Case CVErr(xlErrName)
                 memo = memo & "#NAME?"
            Case CVErr(xlErrNull)
                 memo = memo & "#NULL!"
            Case CVErr(xlErrNum)
                 memo = memo & "#NUM!"
            Case CVErr(xlErrRef)
                memo = memo & "#REF!"
            Case CVErr(xlErrValue)
                memo = memo & "#VALUE!"
            Case Else
               memo = memo & "This should never happen!!"
        End Select
    Else
        memo = memo & dataDB(i,j)
    End If


この記事にはVBAのコードが含まれています。

緑の太文字→注釈
茶色の太文字→条件分岐
赤の太文字→ループ
青の太文字→その他