kazuo様
これで最後にしますので、もう少しお力かしてください。

下記VBAに追加で、今まではA列に〇のみで考えておりましたが、A列の必要箇所に�@〜�Dを入力する
ようにします。
�@をソート印刷をして、以降�A、�B、�C、�Dがあれば、�Dまで印刷を行い、�A以降がなければ印刷をしない
ようにはできないでしょうか？
よろしく願い致します。

　　A　B
1　�@　あ
2　　　あ
3　�A　あ
4　�A　あ
5　　　あ
6　　　あ
7　　　あ
8　�B　あ
9　　　あ
10　


Sub フィルター貼り付け()
    Dim rw As Long
   
    With ActiveSheet
        .Range("A3:L4").CurrentRegion.AutoFilter 1, "〇"
        rw = 4 - .AutoFilter.Range.Row
        .AutoFilter.Range.Offset(rw).Resize(.AutoFilter.Range.Rows.Count - rw).Copy _
            Worksheets("印刷").Range("A4")
        .AutoFilterMode = False
    End With
End Sub

上記VBAに下記のVBAを含めてもらえないでしょうか？
（理解できないで作成しているので不要な箇所は多々あると思います）

　　Sheets("印刷").Select
    Range("Z1:Z4").Copy
    Range("A3").Select
    Selection.End(xlDown).Select
    ActiveCell.Offset(2, 1).Select
    
    ActiveSheet.Paste
    
    Application.CutCopyMode = True
    
    Range("B4:B12").Select
    With Selection.Font
        .ColorIndex = xlAutomatic
        .TintAndShade = 0
    End With
    
    Range("A4:A7").Select
    Selection.NumberFormatLocal = ";;;"
    
    
     Range("B1:L12").Select
    ActiveSheet.PageSetup.PrintArea = "$B$1:$L$12"
    Application.PrintCommunication = False
    
    Application.PrintCommunication = True
    ActiveSheet.PageSetup.PrintArea = "$B$1:$L$12"
    Application.PrintCommunication = False
    With ActiveSheet.PageSetup
        
        .LeftMargin = Application.InchesToPoints(0)
        .RightMargin = Application.InchesToPoints(0)
        .TopMargin = Application.InchesToPoints(0.75)
        .BottomMargin = Application.InchesToPoints(0.55)
        .HeaderMargin = Application.InchesToPoints(0)
        .FooterMargin = Application.InchesToPoints(0)
        .PrintHeadings = False
        .PrintGridlines = False
        .PrintComments = xlPrintNoComments
        .PrintQuality = 600
        .CenterHorizontally = False
        .CenterVertically = False
        .Orientation = xlLandscape
        .Draft = False
        .PaperSize = xlPaperA5
        .FirstPageNumber = xlAutomatic
        .Order = xlDownThenOver
        .BlackAndWhite = False
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = 1
        .PrintErrors = xlPrintErrorsDisplayed
        .OddAndEvenPagesHeaderFooter = False
        .DifferentFirstPageHeaderFooter = False
        .ScaleWithDocHeaderFooter = True
        .AlignMarginsHeaderFooter = True
        
    End With
        
    ActiveWindow.SelectedSheets.PrintOut ActivePrinter:="AAA"

3行目まではよくわからないので、記載しておりません。
書式についても回答無いので、指定しておりません。
該当データが無い場合は以前のままとしています。
Range("Z1:Z4").Copy →�B説明図の.Range("Z1:Z3").Copyとしています。
印刷範囲は上記ペーストした行までとしています。

Sub main()
    Dim cSt As String
    Dim i As Long
    Dim rw As Long
    Dim dSh As Worksheet
    Dim pSh As Worksheet
    Dim dRng As Range
    
    
    cSt = "�@�A�B�C�D"
    Set dSh = Worksheets("data")
    Set pSh = Worksheets("印刷")
    
    pSetUp pSh
    
    With dSh
        .AutoFilterMode = False
        For i = 1 To Len(cSt)
            .Range("A3:L4").CurrentRegion.AutoFilter 1, Mid$(cSt, i, 1)
            rw = 4 - .AutoFilter.Range.Row
            On Error Resume Next
            Set dRng = Nothing
            Set dRng = .AutoFilter.Range.Offset(rw) _
                .Resize(.AutoFilter.Range.Rows.Count - rw).SpecialCells(xlCellTypeVisible)
            On Error GoTo 0
            If dRng Is Nothing Then Exit For
            印刷 pSh, dRng
        Next
        .AutoFilterMode = False
    End With
End Sub

Private Sub 印刷(sh As Worksheet, dRng As Range)
    With sh
        .Range("A4", .Cells(.Rows.Count, "A")).ClearContents
        dRng.Copy .Range("A4")
        .UsedRange.Offset(.Cells(.Rows.Count, "A").End(xlUp).Row).EntireRow.Delete
        .Range("Z1:Z3").Copy .Cells(.Rows.Count, "B").End(xlUp).Offset(2)
        .PageSetup.PrintArea = .Range("L1", .Cells(.Rows.Count, "b").End(xlUp)).Address
'        .PrintOut Preview:=True
        .PrintOut ActivePrinter:="AAA"      '私には無い
    End With
End Sub

Private Sub pSetUp(sh As Worksheet)
    Application.PrintCommunication = False
    With sh.PageSetup
        .LeftMargin = Application.InchesToPoints(0)
        .RightMargin = Application.InchesToPoints(0)
        .TopMargin = Application.InchesToPoints(0.75)
        .BottomMargin = Application.InchesToPoints(0.55)
        .HeaderMargin = Application.InchesToPoints(0)
        .FooterMargin = Application.InchesToPoints(0)
        .PrintHeadings = False
        .PrintGridlines = False
        .PrintComments = xlPrintNoComments
        .PrintQuality = 600                '私のドライバーには無い
        .CenterHorizontally = False
        .CenterVertically = False
        .Orientation = xlLandscape
        .Draft = False
        .PaperSize = xlPaperA5
        .FirstPageNumber = xlAutomatic
        .Order = xlDownThenOver
        .BlackAndWhite = False
        .Zoom = False
        .FitToPagesWide = 1
        .FitToPagesTall = 1
        .PrintErrors = xlPrintErrorsDisplayed
        .OddAndEvenPagesHeaderFooter = False
        .DifferentFirstPageHeaderFooter = False
        .ScaleWithDocHeaderFooter = True
        .AlignMarginsHeaderFooter = True
    End With
    Application.PrintCommunication = True
End Sub