FlyingPanさん、良ければ教えて下さい。

何故、ハイパーリンクではダメなのでしょうか？
（マウスカーソルの問題、クリックの仕方の問題などなど）

Sub macro1()
    Dim shp As Shape
    Dim r As Range
    With ActiveSheet
        Set r = .Range("a1")
        Set shp = .Shapes.AddPicture("C:\Users\kazuo\Documents\test.ico", msoFalse, msoTrue, 0, 0, -1, -1)
        With shp
            .Left = r.Left
            .Top = r.Top
            .Width = r.Width
        End With
        .Hyperlinks.Add Anchor:=shp, Address:="C:\Users\kazuo\Documents\test.pdf"
    End With
End Sub

手作業であればトリミングすれば出来ます。

Sub test()
    Dim r As Range
    With ActiveSheet
        Set r = .Range("a1")
        With .OLEObjects.Add(Filename:="C:\Users\kazuo\Documents\test.pdf", _
            Link:=False, DisplayAsIcon:=True, IconFileName:= _
            "C:\Users\kazuo\Documents\test.ico", IconIndex:=0, IconLabel:="").ShapeRange
            With .PictureFormat '以下は適当です
                .CropTop = 7
                .CropBottom = 32
                .CropLeft = 24
                .CropRight = 24.5
            End With
'            .LockAspectRatio = msoFalse    '縦横比を変える場合
            .Left = r.Left
            .Top = r.Top
            .Width = r.Width
'            .Height = r.Width
        End With
    End With
End Sub

ファイル名で挿入する場合はサイズ指定が出来ないようです。
挿入後にサイズ変更ついでに位置も指定すれば良いでしょう。

Sub test()
    Dim r As Range
    With ActiveSheet
        Set r = .Range("a1")
        With .OLEObjects.Add(Filename:="C:\Users\kazuo\Documents\test.pdf", _
            Link:=False, DisplayAsIcon:=True, IconFileName:= _
            "C:\Users\kazuo\Documents\test.ico", IconIndex:=0, IconLabel:="").ShapeRange
'            .LockAspectRatio = msoFalse    '縦横比を変える場合
            .Left = r.Left
            .Top = r.Top
            .Width = r.Width
'            .Height = r.Width
        End With
    End With
End Sub

Excel2016

excelのworksheet内にpdfファイルを埋め込んでアイコン表示する処理を
VBAで自動化したいと考えています。

マクロ記録で当たりをつけたところ、

ActiveSheet.OLEObjects.Add(Filename:="C:\Users\・・・\test.pdf" _
        , Link:=False, DisplayAsIcon:=True, IconFileName:= _
        "C:\Users\・・・\test.ico", IconIndex:=0, IconLabel:=""). _
        Select

となり、OLEObjects.Addメソッドを調べてみると、width、heightの
引数も使えそうだったので、試してみたのですが、上手くいきません。
意図としては、width:=50,height:=50などとして、アイコンをデフォルトよりも
小さく表示したいのですが、引数を追加すると、寧ろデフォルトよりも
大きく表示され、且つ、数値を変えてもアイコンの大きさは変わりません。

恐らく使い方が間違っているのでしょうが、サンプルコードがなかなか
見つけられず、アドバイス頂けますと大変助かります。

なお、最終的には、Dir関数を用いて、あるフォルダ内のpdfファイルを
worksheet内に抽出して一覧表示させるのを、
（現在はハイパーリンク付きのファイル名表示としているところ）
埋め込みオブジェクトに切り替えたいと考えているのですが、
埋め込む場所（セル）を指定する引数？の使い方もよくわからず、
アドバイスを頂けますと大変助かります。

宜しくお願い致します。

環境：Windows11/Excel365