マナさんいつもありがとうございます！！
例えば、以下のイメージです。

行  _A_  _B_  _C_
 1   あ        い
 2   い        う
 3   う        え
 4   え
 5   お

index関数

Sub test()
    Dim v
    
    v = Range("A1:A5").Value
    v = Application.Index(v, [row(2:4)])
    Range("C1").Resize(UBound(v)).Value = v

End Sub

マナさん

ありがとうございます！！
Application.index自体、全く知らなかったです。。[]というカギかっこの方法も。。

ただ、実際には[row(2:4)]でなくて、[row(cnt:4)]みたいに変数が入るようにしたいので以下をテストしたのですが、どうしてもエラーが出てしまいます。
こちらはどのようにしたらよろしいでしょうか。。

Sub test()
    Dim v
    Dim cnt As Long

    '仮に"2"を入れてテストしました。
    cnt = 2

    v = Range("A1:A5").Value
    v = Application.Index(v, [row(cnt:4)])
    Range("C1").Resize(UBound(v)).Value = v

End Sub

マナさん

ありがとうございます！！以下で成功、うまくいきました。
（いろいろネットで調べても文献が見つからずわからずでしたが、凄いです。。(;;
))

[]の代わりにevaluateというものがあるんですね。

Sub test()
    Dim v
    Dim cnt As Long

    '仮に"2"を入れてテストしました。
    cnt = 2

    v = Range("A1:A5").Value
    v = Application.Index(v, Evaluate("row(" & cnt & ":4)"))
    Range("C1:C3") = v


End Sub

また、これで応用しようと思ったのですが、
以下のような多次元の配列での実現は難しいですか。
いくらやってみてもうまくいかなかったです。

例えば、Range("A2:C4")に対する指定とか、Range("B2:C4")に対する指定とか。。


行  _A_  _B_  _C_
 1   あ   か   さ  
 2   い   き   し  
 3   う   く   す  
 4   え   け   せ
 5   お   こ   そ


もし応用の場面があって実現難しければ、子供バッファを別に用意してそこにfor文でバッファ"v"の指定した部分を入れ込んでいき、子供バッファができあがったらそれをそのままセルにコピペすることで少しでも速度を早くしてみようかとも思いました。。

こうです。

Sub test()
    Dim v
    
    v = Range("A1:C5").Value
    v = Application.Index(v, [{2;3;4}], [{2,3}])
    Range("E1").Resize(UBound(v, 1), UBound(v, 2)).Value = v

End Sub

ちなみに、↓試してみてはどうですか。配列から配列への転記は高速ですよ。

＞子供バッファを別に用意してそこにfor文でバッファ"v"の指定した部分を入れ込んでいき、
＞子供バッファができあがったらそれをそのままセルにコピペすることで
＞少しでも速度を早くしてみようかとも思いました。

以前、Forループで転記しているのを、Indexに書き直したことがありましたが、
遅くなったので、元に戻したことがあります。

今回、下記のようなコードで試してみました。

10000×1000の配列から、5000×500の部分を配列に抜き出す。

Option Explicit
Const rcnt = 10000
Const ccnt = 1000
Dim ary()

Public Sub MakeAry()
    Dim st As Single
    st = Timer

    ReDim ary(1 To rcnt, 1 To ccnt)
    
    Dim r As Long, c As Long
    For r = 1 To rcnt
        For c = 1 To ccnt
            ary(r, c) = "R" & r & "C" & c
        Next
    Next
    Debug.Print "MakeAry", Format(Timer - st, "0.00000")

End Sub

Public Sub testIndex()
    Dim st As Single
    st = Timer
    
    Dim v()
    v = Application.Index(ary, Application.Sequence(5000, , 2500), Application.Sequence(, 500, 250))
    Debug.Print "Index使用", Format(Timer - st, "0.00000")
    
    Application.ScreenUpdating = False
    Worksheets(2).Cells(1).Resize(UBound(v, 1), UBound(v, 2)).Value = v
    Application.ScreenUpdating = True

End Sub

Public Sub testForLoop()
    Dim st As Single
    st = Timer
    
    Dim v()
    Dim w()
    ReDim w(1 To 5000, 1 To 500)
    Dim r As Long, c As Long
    For r = 1 To 5000
        For c = 1 To 500
            w(r, c) = ary(r + 2499, c + 249)
        Next
    Next
    Debug.Print "Forループ使用", Format(Timer - st, "0.00000")
    
    Application.ScreenUpdating = False
    Worksheets(2).Cells(1).Resize(UBound(w, 1), UBound(w, 2)).Value = w
    Application.ScreenUpdating = True

End Sub


当方の環境では、結果は下記になりました。

配列生成      6.26563
Index使用     3.15625
Forループ使用 0.27344

Forループの方が10倍ぐらい速いという結果になりました。





この記事にはVBAのコードが含まれています。

緑の太文字→注釈
茶色の太文字→条件分岐
赤の太文字→ループ
青の太文字→その他