＞今までずっと手作業で切り取り＆貼り付けをしてPDF化して、印刷作業をしてきました。

１．取り敢えず、その作業(１つ目の宛名だけでいいです）の操作をマクロの記録で録って、
　　出来上がったコードをここにアップしてください。

２．エクセルのバージョンは何ですか？
 　 複数種ある場合は、一番古いバージョンを申告してください。

半平太様
早速のご返信ありがとうございます。大変心強いです。


1　操作をマクロの記録です。一応宛名２までやってみました……
いままで別のExcelに切り取って、張り付けてPDF化をしていました。

Sub Macro1()

    '宛名１
    Windows("宛名一覧.xls").Activate
    Range("B1: E12 ").Select ""
    Selection.Cut
    
    Windows("宛名PDF.xlsx").Activate
    Range("B1").Select
    ActiveSheet.Paste
    'ここでPDF化して、印刷しています。
    
    '宛名２
    Windows("宛名一覧.xls").Activate
    Range("F1:I12").Select
    Selection.Cut
    
    Windows("宛名PDF.xlsx").Activate
    Range("B1").Select 'B1
    ActiveSheet.Paste
    'ここでPDF化して、印刷しています。
    
End Sub

2　エクエルのバージョンは以下の通りです。
宛名一覧.xls……Excel97-2003ワークシート
宛名PDF.xlsx……Excelワークシート
これで大丈夫でしょうか？？

＞2　エクエルのバージョンは以下の通りです。
＞宛名一覧.xls……Excel97-2003ワークシート
＞宛名PDF.xlsx……Excelワークシート
＞これで大丈夫でしょうか？？
１．それはバージョンではなく、エクセルブックの「ファイル形式」です。
　　XL2010 とか XL2019 とかMicroSoft365 とかの意味だったのですが、
　　まぁ、大勢に影響がないのでスルーしていただいて結構です。

＞ 'ここでPDF化して、印刷しています。
２．ここの部分はマクロの記録が録れないですか？
　　印刷を先にして、PDFファイルの保存でいいと思うのですが・・(この順序だとマズいのですか？）

　　※なお、Path名とかFileName名は、架空の文字に変更頂いて構いません。

３．各ブックのシート名が不明ですが、各ブックはシートが１枚しかないのですか？

半平太様

ご丁寧にどうもありがとうございます。

2.　について追記致します。
Sub Macro1()

    Range("B1:E12").Select
    Selection.Cut
    Windows("宛名PDF.xlsx").Activate
    Range("B2").Select
    ActiveSheet.Paste
    ChDir "C:\Users\Desktop"
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
        "C:\Users\Desktop\宛名PDF.pdf", Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:= _
        True
End Sub

３．各ブックのシート名はひとつしかありません。
また、増えても特に問題はありません。

すいません。
よろしくおねがいします。

＞    Windows("宛名PDF.xlsx").Activate
＞    Range("B2").Select
貼付け先は、前回B1セルだったんですが、今回はB2セルですね。
どっちが正しいですか？

PDFのファイル名は、それぞれ別名になると思うのですが、どう命名しますか？
名前PDF.pdf　でいいですか？

C9に入っている「名前」って、宛名とは違う気もするんですが、
ただ宛名(１，２，３）がB2セルに入っているのかどうかも
よく分からないのでお聞きします。(B1セルなのかなぁ)


この記事にはVBAのコードが含まれています。

緑の太文字→注釈
茶色の太文字→条件分岐
赤の太文字→ループ
青の太文字→その他

＞いつもの癖で、B1からE12を切り取って張り付けていますが、
＞実際にはB3からD10を選択しても大丈夫です。
１．ちょっと実態が分かりませんが、B1からD12を切り取って、PDFのB1に貼り付けます
２．印刷はPDFにする前に実行しています。
　　マズければ、印刷なしで処理して、後で手作業で一気に印刷してください。
３．OpenAfterPublish:=False 'Trueだと鬱陶しいのでFalseにします、マズければTrueに戻してください。
４．テストは宛先数を２，３件で行ってください。(大量の無駄が出ないように）

Sub setTestDataMacro()
    Const Path As String = "C:\Users\Desktop\"  '←実際の保存フォルダーのパスに変更する(最後に\を付ける)
    
    Dim WsList As Worksheet
    Dim lastRW As Long
    Dim serialNum As Variant
    Dim i As Long, k As Long
    
    Set WsList = Workbooks("宛名一覧.xls").Worksheets(1)
    lastRW = WsList.Cells(WsList.Rows.Count, "B").End(xlUp).Row
    
    For i = 1 To lastRW Step 12
    
        For k = 2 To 6 Step 4
            serialNum = WsList.Cells(i + 9, k + 2).Value
            
            If serialNum <> "" Then '通し番号があれば処理
                WsList.Cells(i, k).Resize(12, 3).Cut '目標宛先範囲を切り取り
                
                Workbooks("宛名PDF.xlsx").Activate
                With ActiveSheet
                    .Range("B1").Select
                    .Paste
                    .PrintOut Copies:=1  '印刷
                    .ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                        Path & serialNum & ".pdf", Quality:=xlQualityStandard, _
                        IncludeDocProperties:=True, _
                        IgnorePrintAreas:=False, OpenAfterPublish:=False 'True
                End With
            Else
                Exit For
            End If
        Next k
    Next i
End Sub


この記事にはVBAのコードが含まれています。

緑の太文字→注釈
茶色の太文字→条件分岐
赤の太文字→ループ
青の太文字→その他

ページ毎なんて話ありましたっけ？

2ページ目の最初の郵便番号の行番号が74は分かりましたが、その前の
1ページ目の最終郵便番号がある行は何行目なんですか？

こんな感じかな？

Sub setTestDataMacro()
    Const Path As String = "C:\Users\Desktop\"  '←実際の保存フォルダーのパスに変更する(最後に\を付ける)
    
    Dim WsList As Worksheet
    Dim lastRW As Long
    Dim serialNum As Variant
    Dim i As Long, k As Long
    Dim page As Long
    
    Set WsList = Workbooks("宛名一覧.xls").Worksheets(1)
    lastRW = WsList.Cells(WsList.Rows.Count, "B").End(xlUp).Row
    
    For page = 1 To Int((lastRW + 68) / 71)
    
        For i = 1 To 71 Step 12 '1ページ12行ずつ、71行目まで処理
            
            For k = 2 To 6 Step 4
                serialNum = WsList.Cells(i + 9 + (page - 1) * 71, k + 2).Value
                
                If serialNum <> "" Then '通し番号があれば処理
                    WsList.Cells(i + (page - 1) * 71, k).Resize(12, 3).Cut '目標宛先範囲を切り取り
                    
                    Workbooks("宛名PDF.xlsx").Activate
                    With ActiveSheet
                        .Range("B1").Select
                        .Paste
                        .PrintOut Copies:=1  '印刷
                        .ExportAsFixedFormat Type:=xlTypePDF, Filename:= _
                            Path & serialNum & ".pdf", Quality:=xlQualityStandard, _
                            IncludeDocProperties:=True, _
                            IgnorePrintAreas:=False, OpenAfterPublish:=False 'True
                    End With
                Else
                    Exit For
                End If
            Next k
        Next i
    Next page
End Sub