戻る  □一般操作のサロン  □ 使用方法  □ 新着記事  □ 新規に質問する!  □ トピック一覧  □ 検索  □ 過去ログ
[ 最新記事及び返信フォームをトピックトップへ ]
このトピック参照回数 :
Outlook操作

    [194471] Outlook操作-

    ■親トピック/記事引用/メール受信=OFF■

    □投稿者/ みら -(2021/12/12(23:08))
    □U R L/
      よろしくお願いします。
      Outlookでエクセルから添付ファイルが2つまであるメールを複数送りたいと思います。
      
      ブックにシートは1つで、受信先情報シートのA列は項目でB列以降にメールに反映
      するデータが入力されています。(1列で1件のメールデータ)
      
      2行目 To
      3行目 cc
      4行目  bcc
      5行目 件名
      6行目 本文
      7〜8行目 添付ファイル
      
      現在添付ファイルはC:\tempに格納しています。添付ファイル名はセル参照として、
      受信先情報シートのB列以降の7〜8行目に「C:\temp\添付ファイル1.zip」のように
      入力していますが現在のコードでうまく動作しています。
      
      これを変更し、添付ファイルの保存先を本マクロ保存ブックと同じ場所にする方法
      をご教授願います。受信先情報シートのB列以降の7〜8行目に、「ThisWorkbook.Path&\添付ファイル1.zip」等を試しましたがうまくいきません
      でした。
      
      現在のコードは以下です。
      
      Option Explicit
      
      Sub Sample()
       
          Dim Outlook As Outlook.Application
          Dim Mail As Outlook.MailItem
          Dim Ws1 As Worksheet
          Dim Attach1 As String       '添付ファイル1
          Dim Attach2 As String       '添付ファイル2
          Dim i As Long
          
          Set Outlook = New Outlook.Application
          
          Set Ws1 = ThisWorkbook.Sheets("受信先情報")
          
          '受信先情報入力列が空になるまで繰り返す
          i = 2
          Do Until Ws1.Cells(2, i) = ""
              
              'Outlookメールを作成
              Set Mail = Outlook.CreateItem(olMailItem)
              
              '送信情報を設定
              With Ws1
                  Mail.To = .Cells(2, i)        '送り先
                  Mail.CC = .Cells(3, i)       'cc
                  Mail.BCC = .Cells(4, i)     'bcc
                  Mail.Subject = .Cells(5, i) '件名
                  Mail.Body = .Cells(6, i)   '本文
                  Attach1 = .Cells(7, i).Value '添付ファイル1
                  Attach2 = .Cells(8, i).Value '添付ファイル2
                  
                  '添付ファイル判定
                  If Attach1 <> "" Then
                      Mail.Attachments.Add Attach1
                  End If
                  
                  If Attach2 <> "" Then
                      Mail.Attachments.Add Attach2
                  End If
                  
                  Mail.BodyFormat = olFormatPlain     'メールの形式
                  
              End With
      
                  'メールプレビュー
                  Mail.Display
      
              i = i + 1
          Loop
          
          'オブジェクトを初期化
          Set Outlook = Nothing
       
      End Sub
      
      
      


      この記事にはVBAのコードが含まれています。

      緑の太文字→注釈
      茶色の太文字→条件分岐
      赤の太文字→ループ
      青の太文字→その他




    [194521] Re[1]: Outlook操作-

    迷宮入りorほかあたって見ます・・ / 記事引用/メール受信=OFF■

    □投稿者/ みら -(2021/12/19(01:45))
    □U R L/

      ご回答がありませんので迷宮入とさせていただきます。
      (他のサイトで質問したいと思ます)




    [194579] Re[2]: Outlook操作-

    記事引用/メール受信=OFF■

    □投稿者/ D -(2022/01/02(18:15))
    □U R L/
      添付ファイルのセルにはファイル名のみ。
      
      Dim strPath As String
      
      '・・・
      
          strPath = ThisWorkbook.Path
          Attach1 = strPath & "\" & .Cells(7, i).Value '添付ファイル1
          Attach2 = strPath & "\" & .Cells(8, i).Value '添付ファイル2
      


      この記事にはVBAのコードが含まれています。

      緑の太文字→注釈
      茶色の太文字→条件分岐
      赤の太文字→ループ
      青の太文字→その他




    [194580] Re[3]: Outlook操作-

    解決!!ありがとうございました! / 記事引用/メール受信=OFF■

    □投稿者/ みら -(2022/01/03(15:05))
    □U R L/

      D様

      ご回答ありがとうございました。

      回答のとおりコードを変更し、コード参照セルの添付ファイル名を「添付ファイル1.zip」としましたら、メールが立ち上がりうまくできました。



このトピック内容の全ページ数 / [0]

このトピックに書きこむ
Name/
E-Mail/

└>このツリーのレス記事をメールで受信しますか? YES/ NO/
Title/
URL/
Comment/ 通常モード->  図表モード-> (←の場合適当に改行を入れて下さい)
タグが使用できます。例 ⇒ <font color="blue">文字</font>
解決!!ありがとうございました! 解決       保留中です・・・ 保留        迷宮入りorほかあたって見ます・・ 迷宮入       すいませ〜ん。誰か〜! Help! ←※回答者専用
解決したらチェック       保留(コードテスト中など・・)         解決不可orレスが全く付かなくてほかのサイトに行くときなど・・
削除キー/
(半角8文字以内) 


- Child Forum -
Edit:ゆう-G